基于虚拟裂纹闭合技术的悬臂梁界面开裂分析

1、建模步骤:

DIS1=.9

DIS2=12

N1=1000

N2=N1

N3=10

DL=100

DH=3

A0=30

NEL=200

NEH=4

TOLER=.1E-5

G1C=.28

G2C=.8

G3C=.8

 

/PREP7

ET,1,182

KEYOPT,1,1,2

KEYOPT,1,3,2

ET,2,182

KEYOPT,2,1,2

KEYOPT,2,3,2

 

ET,3,202

KEYOPT,3,3,2

 

MP,EX,1,1.353E5

MP,EY,1,9E3

MP,EZ,1,9E3

MP,GXY,1,5.2E3

MP,PRXY,1,.24

MP,PRXZ,1,.24

MP,PRYZ,1,.46

 

TB,CGCR,1,,3,LINEAR

TBDATA,1,G1C,G2C,G3C

 

RECTNG,0,DL,DH/2

RECTNG,0,DL,0,-DH/2

 

LSEL,S,LINE,,2,8,2

LESIZE,ALL,DH/NEH

LSEL,INVE

LESIZE,ALL,,,NEL

ALLSEL,ALL

 

LOCAL,11,0,0,0,0

TYPE,1

MAT,1

ESYS,11

AMESH,2

CSYS,0

TYPE,2

ESYS,11

AMESH,1

CSYS,0

 

NSEL,S,LOC,X,A0-TOLER,DL

NUMMRG,NODES

ESLN

 

TYPE,3

MAT,2

CZMESH,,,1,Y,0

 

ALLSEL,ALL

NSEL,S,LOC,X,DL

D,ALL,ALL

NSEL,ALL

 

ESEL,S,ENAME,,202

CM,CPATH,ELEM

NSEL,S,LOC,X,A0

NSEL,R,LOC,Y,0

CM,CRACK1,NODE

ALLSEL,ALL

FINISH

 

/SOLU

CINT,NEW,1

CINT,TYPE,VCCT

CINT,CTNC,CRACK1

CINT,NORM,0,2

CGROW,NEW,1

CGROW,CID,1

CGROW,CPATH,CPATH

CGROW,FCOP,MTAB,1

CGROW,DTIME,2E-3

CGROW,DTMIN,2E-3

CGROW,DTMAX,2E-3

CGROW,FCRA,0.98

 

NSEL,S,LOC,X

NSEL,R,LOC,Y,DH/2

D,ALL,UY,DIS1

 

NSEL,S,LOC,X

NSEL,R,LOC,Y,-DH/2

D,ALL,UY,-DIS1

NSEL,ALL

AUTOTS,ON

TIME,1

NSUB,4,4,4

OUTRES,ALL,ALL

LSWRITE,1

 

TIME,2

NSEL,S,LOC,X

NSEL,R,LOC,Y,DH/2

D,ALL,UY,DIS2

NSEL,S,LOC,X

NSEL,R,LOC,Y,-DH/2

D,ALL,UY,-DIS2

NSEL,ALL

NSUBST,N1,N2,N3

OUTRES,ALL,ALL

LSWRITE,2

 

LSSOLVE,1,2,1

FINISH

 

/POST26

NSEL,S,LOC,Y,DH/2

NSEL,R,LOC,X,0

*GET,NTOP,NODE,0,NUM,MAX

NSEL,ALL

NSOL,2,NTOP,U,Y,UY

RFORCE,3,NTOP,F,Y,FY

/AXLAB,X,DISP U (MM)

/AXLAB,Y,REACTION FORCE R (N)

/YRANGE,0,4

XVAR,2

PLVAR,3

FINISH

 

/POST1

SET,LAST

PLNSOL,S,EQV

ANTIME,100,0.1,,1,2,0,2

 

2、结果显示

 

1

       图1 悬臂梁界面开裂过程

 

1

图2 悬臂端荷载和裂缝宽度曲线